Run detekt using Gradle Task

repositories {
    mavenCentral()
}

configurations {
	detekt
}

def detektTask = tasks.register("detekt", JavaExec) {
	mainClass = "dev.detekt.cli.Main"
	classpath = configurations.detekt

	def input = "$projectDir"
	def config = "$projectDir/detekt.yml"
	def exclude = ".*/build/.*,.*/resources/.*"
	def params = [ '-i', input, '-c', config, '-ex', exclude]

	args(params)
}

dependencies {
	detekt 'dev.detekt:detekt-cli:[detekt_version]'
}

// Remove this line if you don't want to run detekt on every build
check.dependsOn detektTask

repositories {
    mavenCentral()
}

val detekt by configurations.creating

val detektTask = tasks.register<JavaExec>("detekt") {
    mainClass.set("dev.detekt.cli.Main")
    classpath = detekt

    val input = projectDir
    val config = "$projectDir/detekt.yml"
    val exclude = ".*/build/.*,.*/resources/.*"
    val params = listOf("-i", input, "-c", config, "-ex", exclude)

    args(params)
}

dependencies {
    detekt("dev.detekt:detekt-cli:[detekt_version]")
}

// Remove this block if you don't want to run detekt on every build
tasks.check {
    dependsOn(detektTask)
}